#!/usr/bin/perl -w
use strict;

use FindBin qw{$RealBin};
use lib "$RealBin/lib";

use Ripper;

use File::Spec::Functions qw{catfile splitpath};
use File::Path qw{mkpath};
use Getopt::Long qw{:config no_ignore_case no_auto_abbrev};
use Cwd;
use Audio::FLAC::Header;
use MusicBrainz;

GetOptions(
    'device|D=s'  => \my $CD_DEVICE,
    'output|o=s'  => \my $OUTPUT_NAME,
    'force|f'     => \my $FORCE,
    'barcode|b=s' => \my $BARCODE,
    'properties'  => \my $PROPERTIES,
);

# output file
die "Usage: $0 -o <output.flac> [-D <device>]\n" unless $OUTPUT_NAME;
my (undef, $out_dir, $out_file) = splitpath($OUTPUT_NAME);
# automatically add ".flac"
$out_file .= '.flac' unless $out_file =~ /\.flac$/;
# default to current directory
$out_dir ||= getcwd;
mkpath($out_dir) unless -e $out_dir;
my $archive_flac = catfile($out_dir, $out_file);

# check for file exist; default to not overwrite
die "$archive_flac exists\nwill not overwrite (use --force to override this)\n" 
    if -e $archive_flac && !$FORCE;

# get the CD info
$CD_DEVICE ||= '/dev/cdrom';

my $tags = $BARCODE ? { BARCODE => $BARCODE } : {};
my $ripper = Ripper->new({ device => $CD_DEVICE });
my $flac_disc = $ripper->rip_to_flac($archive_flac, $tags);

if ($PROPERTIES) {
    my $info = get_musicbrainz_info({
        discid  => $flac_disc->discid,
        barcode => $flac_disc->barcode,
    });
    if ($info) {
        (my $properties_file = $archive_flac) =~ s/\.flac$/.properties/;
        open my $fh, '>', $properties_file or die "Cannot write $properties_file\n";
        print $fh "$_=$$info{$_}\n" foreach sort keys %{ $info };
        close $fh;
        print "Properties written as $properties_file\n";
    }
}

print "Rip saved as $archive_flac\n";
system 'eject', $CD_DEVICE;